mirror of
https://github.com/Blah-IM/blahrs.git
synced 2025-07-05 13:55:33 +00:00
Package with nix and add systemd unit example
This commit is contained in:
parent
a63d0df443
commit
e84b13c876
9 changed files with 287 additions and 3 deletions
98
nix/module.nix
Normal file
98
nix/module.nix
Normal file
|
@ -0,0 +1,98 @@
|
|||
{ self }:
|
||||
{
|
||||
lib,
|
||||
config,
|
||||
pkgs,
|
||||
...
|
||||
}:
|
||||
let
|
||||
inherit (lib)
|
||||
literalMD
|
||||
mdDoc
|
||||
mkEnableOption
|
||||
mkIf
|
||||
mkOption
|
||||
types
|
||||
;
|
||||
|
||||
cfg = config.services.blahd;
|
||||
|
||||
toml = pkgs.formats.toml { };
|
||||
mkConfigFile =
|
||||
name: config:
|
||||
(toml.generate name config).overrideAttrs (old: {
|
||||
buildCommand =
|
||||
old.buildCommand
|
||||
+ ''
|
||||
${lib.getBin cfg.package}/bin/blahd validate --config $out
|
||||
'';
|
||||
});
|
||||
|
||||
settingsType = types.submodule {
|
||||
freeformType = toml.type;
|
||||
|
||||
# TODO: Auto-generate these options? Now only required options are documented.
|
||||
options = {
|
||||
database.path = mkOption {
|
||||
type = types.path;
|
||||
default = "/var/lib/blahd/db.sqlite";
|
||||
};
|
||||
|
||||
server.listen = mkOption {
|
||||
type = types.str;
|
||||
example = "localhost:8080";
|
||||
};
|
||||
|
||||
server.base_url = mkOption {
|
||||
type = types.str;
|
||||
example = "http://localhost:8080";
|
||||
};
|
||||
};
|
||||
};
|
||||
|
||||
in
|
||||
{
|
||||
options.services.blahd = {
|
||||
enable = mkEnableOption "Blah Chat Server";
|
||||
|
||||
package = mkOption {
|
||||
description = mdDoc "The blahd package to use.";
|
||||
type = types.package;
|
||||
default = self.packages.${pkgs.system}.blahd;
|
||||
defaultText = literalMD "blahd package from its flake output";
|
||||
};
|
||||
|
||||
settings = mkOption {
|
||||
description = ''
|
||||
blahd configuration.
|
||||
Will be ignored if `settingsFile` is non-null.
|
||||
'';
|
||||
type = settingsType;
|
||||
};
|
||||
|
||||
settingsFile = mkOption {
|
||||
description = ''
|
||||
blahd configuration file path.
|
||||
If non-null, this will be used and `settings` will be ignored.
|
||||
'';
|
||||
type = types.nullOr types.path;
|
||||
defaultText = literalMD "generated from `settings`";
|
||||
default = mkConfigFile "blahd.toml" cfg.settings;
|
||||
};
|
||||
};
|
||||
|
||||
config = mkIf cfg.enable {
|
||||
systemd.packages = [ cfg.package ];
|
||||
environment.systemPackages = [ cfg.package ];
|
||||
|
||||
systemd.services."blahd" = {
|
||||
overrideStrategy = "asDropin";
|
||||
|
||||
wantedBy = [ "multi-user.target" ];
|
||||
restartIfChanged = false;
|
||||
stopIfChanged = false;
|
||||
};
|
||||
|
||||
environment.etc."blahd/blahd.toml".source = cfg.settingsFile;
|
||||
};
|
||||
}
|
Loading…
Add table
Add a link
Reference in a new issue